os_kernel/boot/loader.S

; loader
; 位于硬盘第 2 扇区(LBA 地址)
; ----------------------------------------------------------------
%include "boot.inc"
SECTION LOADER vstart=LOADER_BASE_ADDR
LOADER_STACK_TOP equ LOADER_BASE_ADDR

; 构建 GDT 及其内部描述符(GDT 的第 0 个描述符不可用)
GDT_BASE: dd 0x00000000
        dd 0x00000000

CODE_DESC: dd 0x0000FFFF
        dd DESC_CODE_HIGH4

DATA_STACK_DESC: dd 0x0000FFFF
        dd DESC_DATA_HIGH4

VIDEO_DESC: dd 0x80000007   ;limit=(0xbffff-0xb8000)/4k=0x7
        dd DESC_VIDEO_HIGH4 ;此时 dpl 为 0

GDT_SIZE equ $ - GDT_BASE
GDT_LIMIT equ GDT_SIZE - 1
times 120 dd 0   ; 此处预留 60 个描述符的空位

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; total_mem_bytes 用于保存内在容量，以字节为单位，此位置比较好记
; 当前偏移 loader.bin 文件头(4*8+60*8=512 字节)0x200 字节 loader.bin 的加载地址是 0x900
; 故 total_mem_bytes 内存地址是 0xb00
; offset 0x200
total_mem_bytes dd 0
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

SELECTOR_CODE equ (0x0001<<3) + TI_GDT + RPL0 ; 相当于(CODE_DESC - GDT_BASE)/8 + TI_GDT + RPL0 
SELECTOR_DATA equ (0x0002<<3) + TI_GDT + RPL0
SELECTOR_VIDEO equ (0x0003<<3) + TI_GDT + RPL0

; 以下是 gdt 的指针，前 2 个字节是 gdt 界限，后 4 字节是 gdt 起始地址
gdt_ptr dw GDT_LIMIT 
        dd GDT_BASE
loadermsg db '2 loader in real.'
; 人工对齐 total_mem_bytes4+gdt_ptr6+loadermsg17+ards_buf227+ards_nr2, 共 256 字节
ards_buf times 227 db 0    
ards_nr dw 0  ; 用于记录 ARDS 结构数量

;----------------------------------------------------------------
; INT 0x10  功能号：0x13   功能描述： 打印字符串
;----------------------------------------------------------------
; 输入：
; AH 子功能号 13H
; BH = 页码
; BL = 属性（若 AL=00H 或 01H）
; CX = 字符串长度
; (DH、DL) = 坐标(行，列)
; ES:BP = 字符串地址
; AL=显示输出方式
;   0 ---- 字符串中只含显示字符，其显示属性在 BL 中，显示后，光标位置不变
;   1 ---- 字符串中只含显示字符，其显示属性在 BL 中，显示后，光标位置不变
;   2 ---- 字符串中含显示字符和显示属性。显示后，光标位置不变
;   3 ---- 字符串中含显示字符和显示属性。显示后，光标位置改变
; 无返回值
; offset = 0x200 + 0x100 = 0x300
loader_start:
    ;------------------------ 获取物理内存容量 ---------------------------------------
    ; int 15h eax=E820h, edx = 534D4150h('SMAP') 获取内存布局
    xor ebx, ebx         ; 第一次调用时，ebx 值要为 0
    mov edx, 0x534d4150  ; edx 只赋值一次，循环体中不会改变(字符串 SMAP 的 ASCII 码)
    mov di,  ards_buf    ; ards 结构缓冲区  es:di(es mbr.S 中已经赋值)
    .e820_mem_get_loop:
        mov eax, 0xe820      ; 执行 int 0x15 后， eax 值变为 0x534d150, 所以每次执行 Int 前都要更新子功能号
        mov ecx, 20          ; ards 地址范围描述结构大小是 20 字节
        int 0x15
        jc .e820_failed_so_try_e801 ; cf 位为 1 则有错误发生，尝试 0xe801 子功能
        add di, cx                  ; 使 di 增加 20 字节指向缓冲区中新的 ARDS 结构位置
        inc word [ards_nr]          ; 记录 ards 数量
        cmp ebx, 0                  ; 若 ebx 为 0 且 cf 不为 1，这说明 ards 全部返回，当前已是最后一个
        jnz .e820_mem_get_loop

    ; 在所有 ards 结构中，找出(base_addr_low + length_low) 的最大值，即内存的容量
    mov ecx, [ards_nr]  ; 遍历第一个 ards 结构体，循环次数是 ards 的数量
    mov ebx, ards_buf
    xor edx, edx        ; edx 为最大的内存容量，在此先清 0
    .find_max_mem_area:  ; 不需要判断 type 是否为 1， 最大的内存块一定是可被使用的
        mov eax, [ebx]   ; base_addr_low
        add eax, [ebx+8] ; length_low
        add ebx, 20      ; 指向缓冲区中下一个 ards 结构
        cmp edx, eax
        jge .next_ards
        mov edx, eax     ; edx 为总内存大小
    .next_ards:
        loop .find_max_mem_area
        jmp .mem_get_ok
    
    ; int 15h ax=E801h 获取内存大小，最大支持 4G
    ; 返回后， ax cx 值一样， 以 KB 为单位， bx dx 值一样， 以 64KB 为单位
    ; 在 ax 和 cx 寄存器中低 16MB， 在 bx 和 dx 寄存器中为 16MB 到 4GB
    .e820_failed_so_try_e801:
        mov ax, 0xe801
        int 0x15
        jc .e801_failed_so_try_88 ; 若当前 e801 方法失败，就尝试 0x88 方法
        ;;; 1 先算出低 15MB 的内存 ax 和 cx 中是以 KB 为单位的内存数量，将其转换为以 byte 为单位
        mov cx, 0x400 ; 0x400=1024,  cx 和 ax 值一样，cx 用作乘数
        mul cx
        shl edx, 16
        and eax, 0xFFFF 
        or edx, eax
        add edx, 0x100000    ; ax 只是 15MB，故要加 1MB=1024*1024=1048576=0x100000
        mov esi, edx         ; 先把低 15MB 的内存容量存入 esi 寄存器备份
        ;;; 2 再将 16MB 以上的内存转换为 byte 为单位, 寄存器 bx 和 dx 中是以 64KB 为单位的内存数量
        xor eax, eax
        mov ax, bx 
        mov ecx, 0x10000    ; 64*1024=0x10000
        mul ecx             ; 32 位乘法，默认的被乘数是 eax,积为 64 位，高 32 位存入 edx, 低 32 位存入 eax 
        
        add esi, eax        ; 由于些方法只能测试 4G 以内的内存，故 32 位 eax 足够, edx 为 0
        mov edx, esi        ; edx 为总内存大小
        jmp .mem_get_ok

    ; int 15h ah=88h 获取内存大小，只能获取 64MB 之内
    .e801_failed_so_try_88:
        ; int 15 后，ax 存入的是以 KB 为单位的内存容量
        mov ah, 0x88
        int 0x15
        jc .error_hlt
        and eax, 0xffff
        mov cx, 0x400  ; 1024
        mul cx  
        ; 16 位乘法，被乘数是 ax，积为 32 位，高 16 位在 dx 中，低 16 位在 ax 中
        shl edx, 16  ; 把 dx 移动高 16 位
        and eax, 0xFFFF
        or edx, eax  ; 把积的低 16 位组合到 edx 中，成为 32 位的积
        add edx, 0x100000  ; 0x88 子功能只会返回 1MB 以上的内存，故实际内存大小要加上 1MB=1024*1024=1048576=0x100000
        jmp .mem_get_ok

    .error_hlt:
        mov byte [gs:0], 'e'
        mov byte [gs:1], 'r'
        mov byte [gs:2], 'r'
        mov byte [gs:3], 'o'
        mov byte [gs:4], 'r'
        mov byte [gs:5], '_'
        mov byte [gs:6], 'h'
        mov byte [gs:7], 'l'
        mov byte [gs:8], 't'
        jmp $

    .mem_get_ok:
        mov [total_mem_bytes], edx  ; 将内存换为 byte 单位后存入 total_mem_bytes 处

    ; 显示 loadermsg
    ; mov sp, LOADER_BASE_ADDR
    ; mov bp, loadermsg        ; ES:BP = 字符串地址
    ; mov cx, 17               ; CX = 字符串长度
    ; mov ax, 0x1301           ; AH = 13h, AL = 01h
    ; mov bx ,0x001f           ; 页号 0（BH=0）蓝底粉红色(BL=1fh)
    ; mov dx, 0x1800           ; 坐标(行，列)
    ; int 0x10                 ; 10h 号中断

    ;---------------------- 准备进入保护模式 ------------------------------------------
    ; 1 打开 A20
    ; 2 加载 GDT
    ; 3 将 cr0 的 pe 位置 1

    ;-------------------------- 打开 A20 --------------------------------
    in al, 0x92
    or al, 0000_0010b
    out 0x92, al

    ;-------------------------- 加载 GDT --------------------------------
    lgdt [gdt_ptr]

    ;-------------------------- cr0 第 0 位置 1 --------------------------
    mov eax, cr0
    or eax, 0x00000001
    mov cr0, eax 

    jmp dword SELECTOR_CODE:p_mode_start ; 刷新流水线

[bits 32]
p_mode_start:
    mov ax, SELECTOR_DATA
    mov ds, ax 
    mov es, ax 
    mov ss, ax 
    mov esp, LOADER_STACK_TOP
    mov ax, SELECTOR_VIDEO
    mov gs, ax 

    ; ------------------------ 加载内核 kernel ------------------------
    ;!! 加载到 0x70000~0x9fbff, 190KB 的字节空间,kernel 不超过 100KB
    mov eax, KERNEL_START_SECTOR ; kernel.bin 所在的扇区号
    mov ebx, KERNEL_BIN_BASE_ADDR
    mov ecx, 200                 ; 读入的扇区数

    call rd_disk_m_32

    ; 创建页目录及页表并初始化内存位图
    call setup_page

    ; 将描述符表地址及偏移量写入内存 gdt_ptr, 一会用新地址重新加载
    sgdt [gdt_ptr]

    ; 将 gdt 描述符中视频段描述符中的段基地+0xc0000000
    mov ebx, [gdt_ptr + 2] ; gdt_base 地址
    ; 视频段是 3 个段描述符，第个描述符 8 字节， 故 0x18
    ; 段描述符的高 4 字节的第 31～24 位是段基址
    or dword [ebx + 0x18 + 4], 0xC0000000

    ; 将 gdt 的基址加上 0xC0000000 使其成人内核所在的高地址
    add dword [gdt_ptr + 2], 0xC0000000

    add esp, 0xC0000000 ; 将栈指针同样映射到内核地址

    ; 把页目录地址赋给 cr3
    mov eax, PAGE_DIR_TABLE_POS
    mov cr3, eax

    ; 打开 cr0 的 pg 位(第 31 位).
    mov eax, cr0
    or eax, 0x80000000
    mov cr0, eax

    ; 在开启分页后，用 gdt 新的地址重新加载
    lgdt [gdt_ptr]

    ; 初始化 kernel
    jmp SELECTOR_CODE:enter_kernel

    enter_kernel:
        call kernel_init
        mov esp, 0xc009f000
        jmp KERNEL_ENTRY_POINT

    jmp $

; -------------------------- 创建页目录及页表 ----------------------------------------
; 页目录项
;  31            12 11  9   8     7     6     5     4    3     2     1      0
; -----------------------------------------------------------------------------
; | 页表物理页地址   | AVL |  G  |  0  |  D  |  A  | PCD | PWT | US  | RW  |  P  |
; -----------------------------------------------------------------------------
;
;  页表项
;  31            12 11  9   8     7     6     5     4    3     2     1      0
; -----------------------------------------------------------------------------
; |物理页地址31-12  | AVL |  G  | PAT  |  D  |  A  | PCD | PWT | US  | RW  |  P  |
; -----------------------------------------------------------------------------
setup_page:
    ; 先把页目录占用的空间逐字节清 0
    mov ecx, 4096   ; 页目录大小 4KB = 4096B = 0x1000 
    mov esi, 0
    .clear_page_dir:
        mov byte [PAGE_DIR_TABLE_POS + esi], 0
        inc esi
        loop .clear_page_dir
    
    ; 开始创建页目录项(PDE)
    .create_pde:  ; 创建 Page Directory Entry Table
        mov eax, PAGE_DIR_TABLE_POS ; 0x100000
        add eax, 0x1000 ; 此时 eax 为第一个页表的位置及属性 0x100000 + 0x1000 = 0x101000
        mov ebx, eax    ; 此处为 ebx 赋值，是为 .create_pte 做准备，ebx 为基址
        ; 下面将页目录 0 和 0xc00 都存为第一个页表的地址，第个页表 4MB 内存
        ; 这样 0xc03fffff 以下的地址和 0x003fffff 以下的地址都指向相同的页表
        ; 这是为将地址映射为内核地址做准备
        or eax, PG_US_U | PG_RW_W | PG_P ; 页目录项的属性 RW 和 P 位为 1， US 为 1，表示用户属性，所有特权级别都可以访问
        mov [PAGE_DIR_TABLE_POS + 0x0], eax ; 页目录表中的第一个目录项写入第一个页表的位置（0x101000） 及属性 （7）
        mov [PAGE_DIR_TABLE_POS + 0xC00], eax ; 一个页目录项占 4 字节， 0xc00 表示第 768 个页表占用的目录项
        ;; 0x00000000 ~~ 0x3fffffff 是第一个 1 GB 内存
        ;; 0x40000000 ~~ 0x7fffffff 是第二个 1GB 内存
        ;; 0x80000000 ~~ 0xbfffffff 是第三个 1GB 内存
        ;; 0xc0000000 ~~ 0xffffffff 是第四个 1GB 内存
        ;; 0xc00 以上的目录项用于内核空间
        ;; 也就是页表的 0xc0000000 ~~ 0xffffffff 共计 1G 属于内核
        ;; 0x0 ~~ 0xbfffffff 共计 3G 属于用户进程

        sub eax, 0x1000 
        mov [PAGE_DIR_TABLE_POS + 4092], eax ; 1024 * 4 - 4 = 4092 使最后一个目录项指向页目录表自己的地址

    ; 下面创建页表项(PTE)  256 个页表项
    ;; 第 0 页, 分配物理地址 0~0x3fffff 之间的物理页
    ;; 1M 低端内存中，虚拟地址等于物理地址
    mov ecx, 256      ; 1M 低端内存(1024K) / 每页大小 4K = 256
    mov esi, 0
    mov edx, PG_US_U | PG_RW_W | PG_P ; 属性 7， US=1, RW=1,P=1
    .create_pte:  ; 创建 Page Table Entry
        mov [ebx+esi*4], edx  ; 此时ebx=0x101000,第一个页表地址
        add edx, 4096
        inc esi
        loop .create_pte
    
    ; 创建内核其它页表的 PDE
    mov eax, PAGE_DIR_TABLE_POS
    add eax, 0x2000            ; 此时 eax 为第二个页表的位置
    or eax, PG_US_U | PG_RW_W | PG_P ; 页目录项属性都为 1
    mov ebx, PAGE_DIR_TABLE_POS
    mov ecx, 254           ; 范围为第 769 ～ 1022 的所有目录项数量
    mov esi, 769
    .create_kernel_pde:
        mov [ebx+esi*4], eax
        inc esi
        add eax, 0x1000
        loop .create_kernel_pde
    ret

; ----------------------------------------------------------------    
; 读取硬盘数据   
; EAX=LBA 地址 
; EBX=将数据写入的内存地址
; ECX=读取的扇区数
rd_disk_m_32:
; ----------------------------------------------------------------
    mov esi, eax ; 备份 eax
    mov edi, ecx  ; 备份 ecx

    ; 1. 设置要读取的扇区数
    mov dx, 0x1f2 
    mov al, cl
    out dx, al 

    mov eax, esi ; 恢复 eax

    ; 2. 设置 LBA 地址,存入 0x1f3 - 0x1f6 端口中
    ; LBA 地址 7 ～ 0 位写入端口 0x1f3
    mov dx, 0x1f3
    out dx, al

    ; LBA 地址 15 ～ 8 位写入端口 0x1f4
    mov cl, 8
    shr eax, cl ; 右移 8 位
    mov dx, 0x1f4
    out dx, al

    ; LBA 地址 23 ～ 16 位写入端口 0x1f5
    shr eax, cl 
    mov dx, 0x1f5
    out dx, al

    shr eax, cl 
    and al, 0x0f  ; 设置 LBA 地址 24～27 位
    or al, 0xe0   ; 设置 7~4 位为 1110, 表示 LBA 模式
    mov dx, 0x1f6 ; Device
    out dx, al 

    ; 3. 向 0x1f7 端口写入命令 0x20
    mov dx, 0x1f7 ; Command
    mov al, 0x20
    out dx, al

    ; 4. 检测硬盘状态
    ; 使用同一端口0x1f7，写时表示写入命令字，读时表示读入硬盘状态
    .not_ready:
        nop             ; 什么也不做，目的是为了减少对硬盘的打扰
        in al, dx       ; 读入硬盘状态
        and al, 0x88    ; 第 4 位为 1 表示硬盘控制器已准备好数据传输，第 7 位为 1 表示硬盘忙
        cmp al, 0x08
        jnz .not_ready  ; 硬盘没有准备数据传输，继续等待

    ; 5. 从 0x1f0 端口读取数据
    ; di 为要读取的扇区数，一个扇区 512 字节，每次读入一个字，共需要 di*512/2 次，所以 di*256
    mov ax, di
    mov dx, 256
    mul dx      ; dx:ax = ax * 256
    mov cx, ax

    mov dx, 0x1f0
    .go_on_read:
        in ax, dx
        mov [ebx], ax 
        add ebx, 2
        loop .go_on_read

    ret

; ------------------------  将 kernel.bin 中的 segment 拷贝到编译的地址 ------------------------
kernel_init:
    xor eax, eax 
    xor ebx, ebx      ; ebx 记录程序头表地址
    xor ecx, ecx      ; cx 记录程序头表的 program header 数量
    xor edx, edx      ; dx 记录  program header 尺寸，即 e_phentsize

    mov dx, [KERNEL_BIN_BASE_ADDR + 42] ; 偏移文件 42 字节处的属性是 e_phentsize，表示 program header 大小
    mov ebx, [KERNEL_BIN_BASE_ADDR + 28] ; 偏移文件 28 字节的地方是 e_phoff， 表示第 1 个 program header 在文件中的偏移量
    add ebx, KERNEL_BIN_BASE_ADDR
    mov cx, [KERNEL_BIN_BASE_ADDR + 44] ; 偏移文件开始部分 44 字节的地方是 e_phnum, 表示有几个 program header

    .each_segment:
        cmp byte [ebx], PT_NULL ; 若 p_type 等于 PT_NULL，说明此 program header 未使用
        je .PTNULL

        ; 为函数 memycpy 压入参数， 参数是从右到左依然压入
        ; 函数原型 memycpy(dst, src, size)
        push dword [ebx + 16]             ; program header 中偏移 16 字节的地方是 p_filesz 第三个参数： size
        mov eax, [ebx + 4]                ; 距程序头偏移量为 4 字节的位置是 p_offset 
        add eax, KERNEL_BIN_BASE_ADDR     ; 加上 kernel.bin 被加载的物理地址， eax 为该段的物理地址
        push eax                          ; 第二个参数： 源地址 src
        push dword [ebx + 8]              ; 偏移程序头 8 字节位置是p_vaddr, 目的地址
        call mem_cpy                      ; 调用 mem_cpy 完成段自制
        add esp, 12                       ; 清理栈中压入的三个参数

    .PTNULL 
        add ebx, edx                      ; edx 为 program header 大小，此时 ebx 指向下一个 program header  
        loop .each_segment
    ret

; -------------------------------- 逐字节拷贝 mem_cpy(dst, src, size) --------------------------------
; 输入：栈中三个参数 (dst, src, size)
; 输出： 无
; --------------------------------------------------------------------------------------------------
mem_cpy:
    cld     ; mem_cpy 使 DF (Direction Flag) 复位 DF = 0
    push ebp
    mov ebp, esp 
    push ecx     ; rep 指令用到了 ecx, 故先备份

    mov edi, [ebp + 8]   ; dst    ES:DI
    mov esi, [ebp + 12]  ; src    DS:SI
    mov ecx, [ebp + 16]  ; size 
    rep movsb   ; 逐字节拷贝

    ; 恢复环境
    pop ecx
    pop ebp
    ret